uses crt;
var f,g : file of real;                          {f-databaza, g-pomocny subor}
    x,y : real;
    znak : char;

procedure nova;                                    {vytvorenie novej databazy}
 begin
  rewrite(f);
 end;

procedure vypis;                                        {vypis celej databazy}
 var pom : byte;
 begin
  reset(f);pom := 0;
  while not(eof(f)) do begin
                        inc(pom); read(f,x); writeln(x);
                        if pom = 20 then begin readln; pom := 0; end;
                       end;
  readln;
 end;

procedure pridaj;                                 {pridanie prvku do databazy}
 var zapisane : boolean;
 begin
  writeln('Zadaj realne cislo');readln(x);
  assign(g,'pomoc');rewrite(g);reset(f);zapisane := false;
  while not(eof(f)) do begin      {f -> g, novy prvok sa zapise na svoje miesto}
                        read(f,y);
                        if not(zapisane) and (x < y) then begin
                                                           write(g,x);
                                                           zapisane := true;
                                                          end;
                        write(g,y)
                       end;
  if not(zapisane) then write(g,x);           {pripad, ze databaza bola prazdna}
  reset(g);rewrite(f);
  while not(eof(g)) do begin read(g,x); write(f,x); end;                {g -> f}
  close(g);erase(g);
 end;

procedure zmaz;                                               {zmazanie prvku}
 begin
  writeln('Zadaj realne cislo'); readln(x);
  assign(g,'pomoc'); rewrite(g); reset(f);
  while not(eof(f)) do begin               {f -> g, vsetko okrem zadaneho prvku}
                        read(f,y);
                        if x <> y then write(g,y)
                       end;
  rewrite(f); reset(g);
  while not(eof(g)) do begin                                            {g -> f}
                        read(g,y); write(f,y)
                       end;
  close(g); erase(g);
 end;

procedure testuj;                         {test na pritomost prvku v databaze}
 var nachadza : boolean;
 begin
  reset(f);
  nachadza := false;
  writeln('Zadaj cislo');
  readln(x);
  while not(eof(f)) and not(nachadza) do begin         {staci najst prvy vyskyt}
                                          read(f,y);
                                          if x=y then nachadza := true;
                                         end;
  if nachadza then writeln('Prvok ',x,' sa nachadza v databaze')
              else writeln('Prvok ',x,' sa nenachadza v databaze');
  readln;
 end;




begin
 assign(f,'databaza.dat');                    {subor sa otvori raz na zaciatku}
 repeat                                                         {menu programu}
  clrscr;
  writeln('1) Nova databaza');
  writeln('2) Vypis databazu');
  writeln('3) Pridaj do databazy');
  writeln('4) Zmaz prvok');
  writeln('5) Test pritomnosti prvku');
  writeln('k) Koniec');
  znak := readkey;
  case znak of
   '1' : nova;
   '2' : vypis;
   '3' : pridaj;
   '4' : zmaz;
   '5' : testuj;
  end;
 until znak = 'k';
 close(f);                                {subor sa uzatvori na konci programu}
end.